Automatic bandwidth control release by Queue Tree at specific time

Resource Automatic bandwidth control release by Queue Tree at specific time

Automatic bandwidth control release by Queue Tree at specific time

Free

This script frees up bandwidth at a specific time for routers that have the bandwidth control with reuse configuration that we offer on our website.

Compact file autoLiberadorAnchoBanda_v6.x

Download

# Script para liberación de ancho de banda por control de Queue Tree
# Versión de RouterOS: v6.x
#
# Instrucciones:
#     1. Crea un scheculer llamado autoLiberadorAnchoBanda que se ejecute cada minuto
#     2. Dentro pega el código que se muestra a continuación
#     3. Listo, tu scheduler liberará o no el ancho de banda dependiendo
#       del horario programado

# Queue tree a habilitar o deshabilitar
:local queueTree "Total para Reuso";

# Indica el inicio y fin de la liberación de ancho de banda
:local inicioLiberacion "23:00:00";
:local finLiberacion "06:00:00";

:global anchoBandaLiberado;
:local liberarAnchoBanda 0;
:local tiempoActual [/system clock get time];

# Inicialización de la bandera
:if ( [:typeof $anchoBandaLiberado] = "nothing" ) do {
  :set anchoBandaLiberado 0;
};

# Análisis del tiempo y activación de la bandera que indica se debe
# liberar el ancho de banda
# Si el $tiempoActual está DENTRO DEL HORARIO de liberación de ancho de banda
# se manda se activa la bandera liberarAnchoBanda
:if ( $inicioLiberacion < $finLiberacion ) do {
  :if ( $tiempoActual >= $inicioLiberacion && $tiempoActual <= $finLiberacion) do {
    :set liberarAnchoBanda 1;
  };
};

:if ( $inicioLiberacion > $finLiberacion ) do {
  :if ( $tiempoActual >= $inicioLiberacion || $tiempoActual <= $finLiberacion ) do {
    :set liberarAnchoBanda 1;
  };
};

# Si el ancho de banda NO está liberado y $liberarAnchoBanda está en 1,
# indica que se debe liberar el ancho de banda
:if ( $anchoBandaLiberado = 0 && $liberarAnchoBanda = 1  ) do {
  /queue tree set [find name~$queueTree] disabled=yes;
  :set anchoBandaLiberado 1;
};

# Si el ancho de banda está liberado y $liberarAnchoBanda está en 0,
# indica que se debe habilitar el control de ancho de banda
:if ( $anchoBandaLiberado = 1 && $liberarAnchoBanda = 0 ) do {
  /queue tree set [find name~$queueTree] disabled=no;
  :set anchoBandaLiberado 0;
};

Compact file autoLiberadorAnchoBanda_v7.x

Download

# Script para liberación de ancho de banda por control de Queue Tree
# Versión de RouterOS: v7.x
#
# Instrucciones:
#     1. Crea un scheculer llamado autoLiberadorAnchoBanda que se ejecute cada minuto
#     2. Dentro pega el código que se muestra a continuación
#     3. Listo, tu scheduler liberará o no el ancho de banda dependiendo
#       del horario programado

# Queue tree a habilitar o deshabilitar
:local queueTree "Total para Reuso";

# Indica el inicio y fin de la liberación de ancho de banda
:local inicioLiberacion "23:00:00";
:local finLiberacion "06:00:00";

:global anchoBandaLiberado;
:local liberarAnchoBanda 0;
:local tiempoActual [/system/clock/get time];

# Inicialización de la bandera
:if ( [:typeof $anchoBandaLiberado] = "nothing" ) do {
  :set anchoBandaLiberado 0;
};

:if ( $inicioLiberacion > $finLiberacion ) do {
  :if ( $tiempoActual >= $inicioLiberacion || $tiempoActual <= $finLiberacion ) do {
    :set liberarAnchoBanda 1;
  };
};

# Si el ancho de banda NO está liberado y $liberarAnchoBanda está en 1,
# indica que se debe liberar el ancho de banda
:if ( $anchoBandaLiberado = 0 && $liberarAnchoBanda = 1  ) do {
  /queue/tree/set [find name~$queueTree] disabled=yes;
  :set anchoBandaLiberado 1;
};

# Si el ancho de banda está liberado y $liberarAnchoBanda está en 0,
# indica que se debe habilitar el control de ancho de banda
:if ( $anchoBandaLiberado = 1 && $liberarAnchoBanda = 0 ) do {
  /queue/tree/set [find name~$queueTree] disabled=no;
  :set anchoBandaLiberado 0;
};

COMMENTS

JESUS 14/10/2023 13:10 hrs

QUE HACE NO COMPRENDO

Comment.

Rodrigo Andrade 16/10/2023 12:10 hrs

Este script libera el ancho de banda en un horario específico para los routers que tengan la configuración de control de ancho de banda con reuso que ofrecemos en nuestra página web, cualquier duda adicional nos puede contactar vía facebook messenger en @livaur, saludos

Comment.