Desactivador automático de Avoid Load Balance

Recurso Desactivador automático de Avoid Load Balance

Desactivador automático de Avoid Load Balance

Gratis

Desactiva una regla de avoid load balance cuando el acceso a internet por dicho ISP se cae.

Compact file desactivadorAutomaticoDeAvoidLoadBalance_to_ISP1_6.x

###############################################################################
# Scheduler failover para desactivar regla de Avoid Load Balance
# en caso que la ruta no tenga acceso a internet
#
# Sugerencia:
#   1. Llamar al scheduler desactivadorAutomaticoDeAvoidLoadBalance_to_ISP1
#   2. Ejecutarlo cada 30 segundos
###############################################################################

# Declaración de variables principales
:global foIspsCaidosAnt;
:global foRelIspInterfaz;

:local commentReglaAvoidLoadBalanceAControlar "avoidloadbalance_to_ISP1"

# Indica el ID del ISP a verificar si está activo o no
:local idIspPrincipal 1;

# Bandera que indica si el ISP principal a monitorear por el script
# está caido
:local ispPrincipalCaido 0;

# Verifica que el ISP principal no esté caido
:foreach idIsp in=[$foIspsCaidosAnt] do={
    :if ( $idIsp = $idIspPrincipal ) do={
        :set ispPrincipalCaido 1;
    }
}

# Si el ISP principal está activo, se manda a habilitar la regla de
# avoid load balance
:if ( $ispPrincipalCaido = 0 ) do={
    /ip firewall mangle set [ find comment="$commentReglaAvoidLoadBalanceAControlar" disabled=yes ] disabled=no
}

# Si el ISP principal está caido, se manda a desactivar la regla de
# avoid load balance
:if ( $ispPrincipalCaido = 1 ) do={
    /ip firewall mangle set [ find comment="$commentReglaAvoidLoadBalanceAControlar" disabled=no ] disabled=yes
}

Compact file desactivadorAutomaticoDeAvoidLoadBalancePBPccv5_to_ISP1

Descargar

###################################################################################
# Scheduler failover para desactivar regla de Avoid Load Balance para la 
# configuración de balanceo de carga PCC con Failover v5.2
# en caso que la ruta no tenga acceso a internet
#
# Sugerencia:
#   1. Llamar al scheduler desactivadorAutomaticoDeAvoidLoadBalancePBPccv5_to_ISP1
#   2. Ejecutarlo cada 30 segundos
###################################################################################

# Declaración de variables principales
:global foIsps;
:local  isp;
:local  avoidact 0;    # Bandera que indica si la regla avoid está activa

:local commentReglaAvoidLoadBalanceAControlar "avoidloadbalance_to_ISP1"

# Indica el ID del ISP a comprobar si está activo o no
:local idIspAComprobar 1;

# Busca el ISP a comprobar
:foreach ispTmp in=[$foIsps] do={
    :if ( ($ispTmp->"id") = $idIspAComprobar ) do={
        :set isp $ispTmp;
    }
}

/ip firewall mangle;
:set avoidact [:len [ find comment="$commentReglaAvoidLoadBalanceAControlar" disabled=no ]];

# Si el ISP a comprobar está activo, se habilita la regla de avoid load balance
:if ( ($isp->"estado_actual") = 1 && $avoidact = 0 ) do={
    set [ find comment="$commentReglaAvoidLoadBalanceAControlar" disabled=yes ] disabled=no;
}

# Si el ISP principal está caido, se manda a desactivar la regla de
# avoid load balance
:if ( ($isp->"estado_actual") = 0 && $avoidact = 1 ) do={
    set [ find comment="$commentReglaAvoidLoadBalanceAControlar" disabled=no ] disabled=yes;
}

COMENTARIOS

Diego Matos 25/07/2021 19:07 hrs

En caso de tener 4 Proveedores y usar 3 para trafico de Netflix y servicios de streaming y descarga funciona de igual manera?

Comentar