Liberador de ancho de banda en horario específico para ArgusBlack

Recurso Liberador de ancho de banda en horario específico para ArgusBlack

Liberador de ancho de banda en horario específico para ArgusBlack

Gratis

Este script libera el ancho de banda en un horario específico para los routers que están enlazados a ArgusBlack.

Compact file argusblack_liberadorAnchoBanda

# Script para liberación de ancho de banda para ArgusBlack
# Instrucciones:
#     1. Crea un scheculer llamado liberadorAnchoBanda que se ejecute cada minuto
#     2. Dentro pega el código que se muestra a continuación
#     3. Listo, tu scheduler liberará o no el ancho de banda dependiendo
#       del horario programado

# Indica el inicio y fin de la liberación de ancho de banda
:local inicioLiberacion "23:00:00";
:local finLiberacion "06:00:00";

:global anchoBandaLiberado;
:local liberarAnchoBanda 0;
:local tiempoActual [/system clock get time];

# Inicialización de la bandera
:if ( [:typeof $anchoBandaLiberado] = "nothing" ) do {
  :set anchoBandaLiberado 0;
};

# Análisis del tiempo y activación de la bandera que indica se debe
# liberar el ancho de banda
# Si el $tiempoActual está DENTRO DEL HORARIO de liberación de ancho de banda
# se manda se activa la bandera liberarAnchoBanda
:if ( $inicioLiberacion < $finLiberacion ) do {
  :if ( $tiempoActual >= $inicioLiberacion && $tiempoActual <= $finLiberacion) do {
    :set liberarAnchoBanda 1;
  };
};

:if ( $inicioLiberacion > $finLiberacion ) do {
  :if ( $tiempoActual >= $inicioLiberacion || $tiempoActual <= $finLiberacion ) do {
    :set liberarAnchoBanda 1;
  };
};

# Si el ancho de banda NO está liberado y $liberarAnchoBanda está en 1,
# indica que se debe liberar el ancho de banda
:if ( $anchoBandaLiberado = 0 && $liberarAnchoBanda = 1  ) do {
  /queue tree set [find name~"argusblack_"] disabled=yes;
  :set anchoBandaLiberado 1;
};

# Si el ancho de banda está liberado y $liberarAnchoBanda está en 0,
# indica que se debe habilitar el control de ancho de banda
:if ( $anchoBandaLiberado = 1 && $liberarAnchoBanda = 0 ) do {
  /queue tree set [find name~"argusblack_"] disabled=no;
  :set anchoBandaLiberado 0;
};

COMENTARIOS

ELio Feliciano 20/05/2021 23:05 hrs

Funciona con pCC ?

Comentar

Rodrigo Andrade 21/05/2021 09:05 hrs

Hola, solo funciona en RB que tengan usando el sistema de administración WISP Argus Black.

Comentar