Restablecedor de conexión a internet de interfaces DHCP (Auto release para interfaces cliente DHCP que pierden conexión a internet)

Recurso Restablecedor de conexión a internet de interfaces DHCP (Auto release para interfaces cliente DHCP que pierden conexión a internet)

Restablecedor de conexión a internet de interfaces DHCP (Auto release para interfaces cliente DHCP que pierden conexión a internet)

Gratis

Si tus servicios de internet pierden conexión a internet periódicamente y necesitas realizar un release de la interfaz para obtener la nueva configuración de tu proveedor de internet, este script monitorea el servicio y realiza el trabajo automáticamente.

Instructivo

Compact file autoReleaseWanDHCP_v6.x

Descargar

################################################################################
# Script que lanza un auto release cuando la interfaz
# del cliente DHCP no tiene internet
# Para RouterOS v6.x
################################################################################

# Nombre de la interfaz usada por el cliente DHCP
:local clienteDhcp "ether1";

# Dirección IP del host externo a donde se realizarán las pruebas de ping
:local direccionIpHostExterno "8.8.4.4";

# Cantidad de pruebas de ping a realizar
:local npings 5;

# Definición de variables para uso del script
:local gateway;
:local gatewayAux;
:local idRutaMonitoreo;
:local rping 0;

/ip dhcp-client;

# Obtención del gateway de la interfaz
:set gateway [get [find interface="$clienteDhcp"] gateway];

/ip route;

# Registro de ruta para monitoreo de internet por Cliente DHCP
:if ( [:len [find routing-mark="monitorinternet_$clienteDhcp"]] = 0 ) do={
  add gateway=$gateway routing-mark="monitorinternet_$clienteDhcp";
};

# Actualización del gateway de la ruta de monitoreo si el gateway cambió
:set idRutaMonitoreo [find routing-mark="monitorinternet_$clienteDhcp"];
:set gatewayAux [get $idRutaMonitoreo gateway];
:if ( [:len $idRutaMonitoreo] = 1 && $gateway != $gatewayAux ) do={
  set $idRutaMonitoreo gateway=$gateway;
};

# Realización de pruebas de ping
:set rping [ping $direccionIpHostExterno count=$npings size=28 routing-table="monitorinternet_$clienteDhcp"];

# Si no hubo respuesta de ping, indica que no tiene servicio de internet
# y se manda a liberar el cliente DHCP para volver a obtener la configuración
# DHCP del proveedor de internet
:if ( $rping = 0 ) do={
  /ip dhcp-client;
  release $clienteDhcp;
  :delay 3;
  :set gateway [get [find interface="$clienteDhcp"] gateway];

/ip route;
  :set gatewayAux [get $idRutaMonitoreo gateway];
  :if ( $gateway != $gatewayAux ) do={
    set $idRutaMonitoreo gateway=$gateway;
  };
};

Compact file autoReleaseWanDHCP_v7.x

Descargar

################################################################################
# Script que lanza un auto release cuando la interfaz
# del cliente DHCP no tiene internet
# Para RouterOS v7.x
################################################################################

# Nombre de la interfaz usada por el cliente DHCP
:local clienteDhcp "ether1";

# Dirección IP del host externo a donde se realizarán las pruebas de ping
:local direccionIpHostExterno "8.8.4.4";

# Cantidad de pruebas de ping a realizar
:local npings 5;

# Definición de variables para uso del script
:local gateway;
:local gatewayAux;
:local idRutaMonitoreo;
:local rping 0;

/ip/dhcp-client;

# Obtención del gateway de la interfaz
:set gateway [get [find interface="$clienteDhcp"] gateway];

/ip/vrf;

# Registro del VRF para monitoreo de internet por el cliente DHCP
:if ( [:len [find name="monitorinternet_$clienteDhcp"]] = 0 ) do={
  add interface=none name="monitorinternet_$clienteDhcp";
};

/ip/route;

# Registro de ruta para monitoreo de internet por Cliente DHCP
:if ( [:len [find routing-table="monitorinternet_$clienteDhcp"]] = 0 ) do={
  add gateway=$gateway routing-table="monitorinternet_$clienteDhcp" check-gateway=ping;
};

# Actualización del gateway de la ruta de monitoreo si el gateway cambió
:set idRutaMonitoreo [find routing-table="monitorinternet_$clienteDhcp"];
:set gatewayAux [get $idRutaMonitoreo gateway];
:if ( [:len $idRutaMonitoreo] = 1 && $gateway != $gatewayAux ) do={
  set $idRutaMonitoreo gateway=$gateway;
};

# Realización de pruebas de ping
:set rping [ping $direccionIpHostExterno count=$npings size=28 vrf="monitorinternet_$clienteDhcp"];

# Si no hubo respuesta de ping, indica que no tiene servicio de internet
# y se manda a liberar el cliente DHCP para volver a obtener la configuración
# DHCP del proveedor de internet
:if ( $rping = 0 ) do={
  /ip/dhcp-client;
  release $clienteDhcp;
  :delay 3;
  :set gateway [get [find interface="$clienteDhcp"] gateway];

/ip/route;
  :set gatewayAux [get $idRutaMonitoreo gateway];
  :if ( $gateway != $gatewayAux ) do={
    set $idRutaMonitoreo gateway=$gateway;
  };
};

COMENTARIOS

Ningún comentario por el momento