Bloqueo de Snapchat

Recurso Bloqueo de Snapchat

Bloqueo de Snapchat

Gratis

Configuración que bloquea el tráfico que va a Snapchat usando Layer 7

Compact file bloqueoSnapchat

##################################################################################################################
#
# Configuración que bloquea el tráfico que va a SnapChat
#
##################################################################################################################

##################################################################################################################
# 1. Configuración estándar para dar acceso a internet al router y a los usuarios de la red LAN
##################################################################################################################

# 1.1. Se configura un cliente DHCP para que el router tenga acceso
/ip dhcp-client
add disabled=no interface=ether1

# 1.2. Se registra un NAT para el tráfico que salga por el puerto ether1; para así enmascararlo con la 
#	dirección IP del puerto ether1
/ip firewall nat
add action=masquerade chain=srcnat out-interface=ether1

# 1.3. Creación del bridgeLAN y asignación de puertos
/interface bridge
add name=bridgeLAN

/interface bridge port
add bridge=bridgeLAN interface=ether2
add bridge=bridgeLAN interface=ether3
add bridge=bridgeLAN interface=ether4
add bridge=bridgeLAN interface=ether5

# Si se requiere trabajar con la interfaz wlan, después de importar esta configuración,
# importa el compact file "configuracionWLAN1.rsc"

# 1.4 Registro de la dirección IP para la red LAN
/ip address
add address=172.16.20.1/24 interface=bridgeLAN network=172.16.20.0

# 1.5. Configuración del Servidor DHCP
/ip pool
add name=poolLAN ranges=172.16.20.2-172.16.20.254

/ip dhcp-server
add address-pool=poolLAN disabled=no interface=bridgeLAN name=dhcp1

/ip dhcp-server network
add address=172.16.20.0/24 dns-server=8.8.4.4,8.8.8.8 gateway=172.16.20.1

# 1.6. Se activa la bandera allow-remote-request para permitir al router resolver los dominios 
# 	solicitados por los usuarios
/ip dns
set allow-remote-requests=yes

##################################################################################################################
# 2. Bloqueo de Snapchat
##################################################################################################################

# 2.1. Se define el patrón RegExp con el cual buscaremos coincidencias en los paquetes para encontrar aquel 
#	que vaya a snapchat.com
/ip firewall layer7-protocol
add name=snapchat regexp="(snapchat.com|snapads.com|snap-storage-cdn.l.google.com).*"

# 2.2. Se definirán un par de reglas Mangle para marcar la conexión y paquetes relacionados con Snapchat
/ip firewall mangle

# 2.2.1. Esta regla se usará para marcar la conexión del tráfico que intente establecerse a Snapchat
add chain=prerouting in-interface=bridgeLAN \
    layer7-protocol=snapchat \
    action=mark-connection new-connection-mark=snapchat_conn passthrough=yes \
    comment="Marcado de conexión a Snapchat usando Layer 7"

# 2.2.2. Aquí se marcan los paquetes de la conexión marcada previamente.
add chain=prerouting connection-mark=snapchat_conn \
    action=mark-packet new-packet-mark=snapchat_pkt passthrough=no \
    comment="Marcado de paquetes para el tráfico a Snapchat"

# 2.3. Se filtran los paquetes snapchat_pkt, y estos se mandan a rechazar. 
#	Ya que se pretende evitar que el cliente final, logre establecer una conexión
# 	con los servidores de Snapchat.
/ip firewall filter
add chain=forward packet-mark=snapchat_pkt \
	action=reject reject-with=icmp-host-prohibited \
    comment="Bloqueo de paquetes que van a Snapchat"

Compact file configuracionWLAN1

Descargar

# Configuración para habilitar la interfaz WLAN1
/interface wireless
set [ find default-name=wlan1 ] disabled=no mode=ap-bridge ssid="Mi internet" \
    wireless-protocol=802.11

/interface wireless security-profiles
set [ find default=yes ] supplicant-identity=MikroTik

/interface bridge port
add bridge=bridgeLAN interface=wlan1
/system note
    set note="\
        \n\\n\
        \n\
        \n\
        \n\
        \n\
        \n\
        \n\
        \n\
        \n\
        \n\
        \n\
        \n\
        \n\
        \n\
        \n\
        \n\
        \n\
        \n\
        \n\
        \n\
        \n\
        \n\
        \n\
        \n\
        \n\
        \n\
        \n\
        \n\
        \n\
        \n\
        \n\
        \n\
        \n\
        \n\
        \n\
        \n\
        \n\
        \n\
        \n\
        \n\
        \n    LL       IIIIIII  VV     VV   AAAAAAA  UU   UU  RRRRRRR        \
        \n    LL         III    VV     VV   AA   AA  UU   UU  RR   RR     \
        \n    LL         III     VV   VV    AA   AA  UU   UU  RRRRRRR     \
        \n    LL         III     VV   VV    AAAAAAA  UU   UU  RR  RR      \
        \n    LL         III      VV VV     AA   AA  UU   UU  RR   RR     \
        \n    LLLLLLL  IIIIIII     VVV      AA   AA  UUUUUUU  RR    RR     \
        \n\
        \n\
        \n                        www.livaur.com \
        \n\
        \n_______________________________________________________________\
        \n\
        \n               CONFIGURACIONES EQUIPOS MIKROTIK      \
        \n_______________________________________________________________\
        \n\
        \n         Para soporte Escribenos en nuestro chat        \
        \n    de nuestra pagina web o al correo redes3@livaur.com        \
        \n         o llamenos al (594) 958 2511 ext. 604       \
        \n\
        \n"

COMENTARIOS

Ningún comentario por el momento